/\*\*\* Mesures de débits sur un banc hydraulique affichage LCD et Bluetooth \*\*\*/

#include <LiquidCrystal.h> // ajout de la bibliothèque de l'afficheur

LiquidCrystal lcd(7, 6, 5, 4, 3, 2); // broches sur lesquelles l'afficheur est connecté

#include <SoftwareSerial.h> // chargement de la bibliothèque Bluetooth

#include <math.h> // chargement de la bibliothèque math

SoftwareSerial hc06(8,9); // broches sur lesquelles le module Bluetooth est connecté

// Définition des numéros de broches pour US

const int trigPin = 11; // Trigger (émission)

const int echoPin = 12; // Echo (réception)

// Variables utiles

long duree; // durée de l'écho

float tension; // tension capteur temp

int val;

float son; // vitesse du son dans l'air

float temp; // température de l'air

float trajet; // trajet aller parcouru

float distance; // distance obstacle

float niveau; // niveau d'eau dans le banc hydraulique

float alpha = 53.13;

float debit = 0.;

float h; // hauteur lame en cm

void setup()

{

  pinMode(A2,INPUT); // tension connectée sur l'entrée analogique A2

  pinMode(trigPin, OUTPUT); // configuration du port du Trigger comme SORTIE

  pinMode(echoPin, INPUT); // configuration du port de l'Echo  comme ENTREE

  lcd.begin (16,2); // utilisation d’un écran 16 colonnes et 2 lignes

  hc06.begin(9600); // initialisation de la liaison Bluetooth

}

void loop()

{

  // Mesure température

  val=analogRead(A2); // tension sur la broche A2 dans la variable val

  tension = val\*(5.0/1023); // conversion de la tension en V

  temp = tension\*100.;

  // Émission d'un signal de durée 10 microsecondes

  digitalWrite(trigPin, LOW);

  delayMicroseconds(5);

  digitalWrite(trigPin, HIGH);

  delayMicroseconds(10);

  digitalWrite(trigPin, LOW);

  // Écoute de l'écho

  duree = pulseIn(echoPin, HIGH);

  // Calcul de la distance

  son = (0.6\*temp+331.)/10000.; //calcul de la vitesse du son

  trajet = duree\*son/2;

  distance = sqrt((trajet\*trajet-2.4\*2.4/4)); // distance de l'obstacle

  niveau = 14.8-distance;

  h = (niveau-7.5)\*1.e-2; // calcul de la lame d'eau h en m

  debit = 1.32\*tan(alpha\*3.14/360.)\*powf(h,2.47)\*1000.; // formule de Gourley

  lcd.setCursor (0, 0);

//Position du curseur sur la première colonne et première ligne

  lcd.print("niveau : ");

  lcd.print(niveau);

  lcd.print("cm");

  // Affichage de la distance et du niveau d'eau sur l'afficheur

  lcd.setCursor (0,1);

  //Position du curseur sur la première colonne et la deuxième ligne

  lcd.print("debit : ");

  lcd.print(debit);

  lcd.print("L/s");

  delay(500);

  if(hc06.available()>0)

  {

    hc06.println();

    hc06.print("debit = "); // écrit le texte sur le module Bluetooth

    hc06.print(debit);

    //Écrit la valeur correspondante de la tension en V sur le module Bluetooth

    hc06.print("L/s");

  }

}